4 votos

¿Cómo "Responder a todos" y mantener el archivo adjunto original en Outlook?

¿Cómo podría realizar una "Respuesta a todos" en Outlook, pero reenviando el archivo adjunto original de nuevo a todos?

4voto

Daniel Silveira Puntos 8553

Aparentemente no sin un código VBA. Aquí hay algo que encontré que pretende hacer exactamente eso. ( Fuente )

Descripción: Esta muestra de VBA de Outlook crea y muestra una respuesta al mensaje actualmente abierto o seleccionado incluyendo los archivos adjuntos en el original.

Sub ReplyWithAttachments()
    Dim rpl As Outlook.MailItem
    Dim itm As Object

    Set itm = GetCurrentItem()
    If Not itm Is Nothing Then
        Set rpl = itm.Reply
        CopyAttachments itm, rpl
        rpl.Display
    End If

    Set rpl = Nothing
    Set itm = Nothing
End Sub

Function GetCurrentItem() As Object
    Dim objApp As Outlook.Application

    Set objApp = Application
    On Error Resume Next
    Select Case TypeName(objApp.ActiveWindow)
        Case "Explorer"
            Set GetCurrentItem = objApp.ActiveExplorer.Selection.Item(1)
        Case "Inspector"
            Set GetCurrentItem = objApp.ActiveInspector.CurrentItem
    End Select

    Set objApp = Nothing
End Function

Sub CopyAttachments(objSourceItem, objTargetItem)
   Set fso = CreateObject("Scripting.FileSystemObject")
   Set fldTemp = fso.GetSpecialFolder(2) ' TemporaryFolder
   strPath = fldTemp.Path & "\"
   For Each objAtt In objSourceItem.Attachments
      strFile = strPath & objAtt.FileName
      objAtt.SaveAsFile strFile
      objTargetItem.Attachments.Add strFile, , , objAtt.DisplayName
      fso.DeleteFile strFile
   Next

   Set fldTemp = Nothing
   Set fso = Nothing
End Sub

Notas sobre el código:

  1. Utiliza el GetCurrentItem() función para devolver el artículo actualmente seleccionado o mostrado.

  2. Utiliza el CopyAttachments() procedimiento para copiar los anexos de la respuesta.

  3. Reemplazar itm.Reply con itm.ReplyAll si prefieres responder a todos.

(Oh, y encontré esto en unos 30 segundos haciendo una búsqueda en la web de "responder a todos los que tienen adjuntos en perspectiva").

1voto

Crujach Puntos 208

Posible solución:

La persona que envía este correo la primera vez abre su carpeta de "Elementos enviados", abre el correo y selecciona Acciones - "Reenviar este mensaje...." otra vez.

EnMiMaquinaFunciona.com

EnMiMaquinaFunciona es una comunidad de administradores de sistemas en la que puedes resolver tus problemas y dudas.
Puedes consultar las preguntas de otros sysadmin, hacer tus propias preguntas o resolver las de los demás.

Powered by: