20 votos

SQL Server 2008 Express - ¿la "mejor" solución de copia de seguridad?

¿Qué soluciones de respaldo recomendaría al usar SQL Server 2008 Express ? Soy bastante nuevo en el Servidor SQL, pero como vengo de un MySQL fondo pensé en establecer una réplica en otro ordenador y simplemente tomar Xcopy copias de seguridad de ese servidor.

Pero desafortunadamente la réplica no está disponible en la Edición Express.

El sitio es de gran acceso, por lo que no tiene que haber retrasos ni tiempos de inactividad. También estoy pensando en hacer una copia de seguridad dos veces al día o algo así.

¿Qué me recomienda? Tengo varios ordenadores que puedo usar, pero no sé si eso me ayuda ya que estoy usando la versión Express.

30voto

Bob Puntos 34449

SQL Server Express 2008 es compatible con las copias de seguridad de las bases de datos. Le falta SQL Agent, que permite programar las copias de seguridad, y el asistente del plan de mantenimiento para crear una copia de seguridad de las tareas.

Puedes hacer una copia de seguridad de las bases de datos de dos maneras diferentes:

  1. Utilice Microsoft SQL Server Management Studio Express que tiene la opción de copia de seguridad en el menú de clic derecho para cada base de datos en "tareas".
  2. Usa T-SQL para escribir manualmente tu copia de seguridad script. Lee el Documentación MSDN para el comando T-SQL BACKUP .
    Sintaxis algo así como: BACKUP DATABASE MyDatabase TO DISK='C:\MyDatabase.bak';

Si quieres programar tus trabajos de copia de seguridad, tienes que escribir un T-SQL script y luego usar la Agenda de Tareas de Windows para llamar a SQLCmd para ejecutar el script en lo que cada horario te interesa:

 sqlcmd -s server_name\sqlexpress -i C:\SqlJobs\backup.sql -o C:\Logs\output.txt

5voto

Aleksandar Puntos 721

Me escribieron una copia de seguridad script para usarla yo mismo, instalarla como se menciona en el post de splattne :

----- Version: 2.0 - 2009-12-12 - SQL 2000 Compatible
----- Pham Kim Ngan (jbngan@gmail.com)
----- Usage:
-- Copy 7za.exe (http://www.7-zip.org/download.html - Command Line Version) to @CFG_BACKUP_PATH
-- Modify @CFG_BACKUP_PATH = <Backup Store Path> - no long filename/directory please
-- Modify @CFG_DAYS_DELETE = Days to keep backups
-- Enable 'xp_cmdshell' (SQL 2005/EXPRESS or higher)

----- Configuration Variables
DECLARE @CFG_BACKUP_PATH NVARCHAR(256)
DECLARE @CFG_DAYS_DELETE INT

SET @CFG_BACKUP_PATH = 'C:\DatabaseBackup'
SET @CFG_DAYS_DELETE = 30

DECLARE @Today DATETIME
DECLARE @TodayName CHAR(8)
SET @Today = GETDATE()
SET @TodayName = CONVERT(CHAR(8), @Today, 112)

DECLARE @id INT
DECLARE @name VARCHAR(50)
DECLARE @path VARCHAR(256)
DECLARE @cmd VARCHAR(256)

----- Create Temporarity Directory
DECLARE @TempDir VARCHAR(256)
SET @TempDir = @CFG_BACKUP_PATH + '\' + CONVERT(VARCHAR(256), NEWID())
SET @cmd = 'md ' + @TempDir
EXEC xp_cmdshell @cmd, no_output

----- List of current databases, only 'ONLINE' databases to be backup
DECLARE @dbList TABLE
    (
      dbno INT IDENTITY,
      dbname NVARCHAR(256)
    )

INSERT  INTO @dbList ( dbname )
        SELECT  name
        FROM    master.dbo.sysdatabases
        WHERE   ( name NOT IN ( 'tempdb' ) )
                AND DATABASEPROPERTYEX(name, 'Status') = 'ONLINE'

------ Starting backup, one by one
SELECT  @id = dbno,
        @name = dbname
FROM    @dbList
WHERE   dbno = 1
WHILE @@ROWCOUNT = 1
    BEGIN
        PRINT N'++ Backup: ' + @name
        SET @path = @TempDir + '\' + @name + '.bak'

        BACKUP DATABASE @name TO DISK = @path

        SELECT  @id = dbno,
                @name = dbname
        FROM    @dbList
        WHERE   dbno = @id + 1
    END

PRINT N'++ Compressing: ' + @TempDir

----- Delete output file if existed
SET @cmd = 'del /f /q ' + @CFG_BACKUP_PATH + '\' + @TodayName + '.ZIP'
EXEC xp_cmdshell @cmd, no_output

DECLARE @Count INT
DECLARE @StartTime DATETIME
SET @StartTime = GETDATE()
----- Compress, -mx1 = Set Compression Ratio to 1 (very low)
SET @cmd = @CFG_BACKUP_PATH + '\7za.exe a -bd -y -tzip -mx1 '
SET @cmd = @cmd + @CFG_BACKUP_PATH + '\' + @TodayName + '.ZIP ' + @TempDir + '\*.bak"'
EXEC xp_cmdshell @cmd, no_output

SET @Count = DATEDIFF(second, @StartTime, GETDATE())
PRINT N'++ Compression Time: ' + CONVERT(VARCHAR, @Count) + ' seconds'
SET @Count = DATEDIFF(second, @Today, GETDATE())
PRINT N'++ Total Execution Time: ' + CONVERT(VARCHAR, @Count) + ' seconds'

---- Delete temporarity directory
SET @cmd = 'rd /s /q ' + @TempDir
EXEC xp_cmdshell @cmd, no_output

---- Delete previous backup versions
DECLARE @OlderDateName CHAR(8)
SET @OlderDateName = CONVERT(CHAR(8), @Today - @CFG_DAYS_DELETE, 112)

----- List all .ZIP files
CREATE TABLE #delList
    (
      subdirectory VARCHAR(256),
      depth INT,
      [file] BIT
    )
INSERT  INTO #delList
        EXEC xp_dirtree @CFG_BACKUP_PATH, 1, 1
DELETE  #delList
WHERE   RIGHT(subdirectory, 4) <> '.ZIP'

SELECT  @Count = COUNT(1)
FROM    #delList
PRINT N'++ Number of Backups: ' + CONVERT(NVARCHAR, @Count)

SELECT TOP 1
        @name = subdirectory
FROM    #delList
WHERE   LEN(subdirectory) = 12
        AND RIGHT(subdirectory, 4) = '.ZIP'
        AND REPLACE(subdirectory, '.ZIP', '') < @OlderDateName

WHILE ( @@ROWCOUNT = 1 ) 
    BEGIN
        PRINT N'++ Delete Older Backup: ' + @name
        SET @cmd = 'del /f /q ' + @CFG_BACKUP_PATH + '\' + @name
        EXEC xp_cmdshell @cmd, no_output

        DELETE  #delList
        WHERE   subdirectory = @name

        SELECT TOP 1
                @name = subdirectory
        FROM    #delList
        WHERE   LEN(subdirectory) = 12
                AND RIGHT(subdirectory, 4) = '.ZIP'
                AND REPLACE(subdirectory, '.ZIP', '') < @OlderDateName
    END

DROP TABLE #delList

PRINT N'++ Done.'
PRINT ''
PRINT ''
PRINT ''

2voto

CPU_BUSY Puntos 1978

Yo uso ExpressMaint y funciona muy bien como una tarea programada. Sólo tienes que pasar los parámetros apropiados para el tipo de trabajo que estás haciendo.

El código fuente también está ahí fuera. Lo cambiamos ligeramente para añadir una entrada en el registro de eventos de la aplicación en caso de fallo.

1voto

Guppy Puntos 93

Basado en Bajo el puesto de Fold Busqué en Google y encontré los detalles de ExpressMaint. No había visto esto antes, así que estoy muy contento de haberlo encontrado.

Para tu información, la página web es, http://expressmaint.codeplex.com/

Luego usé uno de los ejemplos que encontré para crear este archivo por lotes que he programado para ejecutarse durante la noche todos los días.

c:\expressmaint\expressmaint -S (local)\SQLExpress -D ALL_USER -T DB -R E:\backups\sqlexpress\backupreports -RU WEEKS -RV 1 -B E:\backups\sqlexpress -BU DAYS -BV 4 -V -C

Esto toma una copia de seguridad, mantiene cada copia de seguridad ( -BU ) durante cuatro días, así que se obtiene un historial si hay corrupción. Los registros ( -RU ) se mantienen durante una semana.

Sólo he estado usándolo durante unas semanas, pero he estado muy contento con él, ya que es un enfoque de no intervención. Localmente pongo las copias de seguridad en un segundo disco, y luego uso JungleDisk para hacer una copia de seguridad externa a la Amazon EC2 almacenamiento en la nube.

0voto

Estoy usando un programador de Windows para hacer una copia de seguridad de la base de datos de SQL Server Express cada pocas horas usando un archivo por lotes. Parece funcionar bien.

EnMiMaquinaFunciona.com

EnMiMaquinaFunciona es una comunidad de administradores de sistemas en la que puedes resolver tus problemas y dudas.
Puedes consultar las preguntas de otros sysadmin, hacer tus propias preguntas o resolver las de los demás.

Powered by: