Microsoft Windows - Instalar actualizaciones y reiniciar (en lugar de instalar y apagar)

Veo que es una pregunta antigua, pero ahora es posible instalar actualizaciones y luego reiniciar usando Powershell. Específicamente, usted necesita descargar e instalar el Módulo PowerShell de Windows Update . A continuación, puede ejecutar el comando Get-WUInstall -AcceptAll -AutoReboot (hay otros interruptores y argumentos para controlar qué actualizaciones se instalan). Esto hará que Windows descargue las actualizaciones, las instale y se reinicie cuando haya terminado. En mi opinión, esto es genial para los servidores, porque se puede ejecutar un comando y luego salir.

La instalación de actualizaciones durante el reinicio/apagado tiene ciertas ventajas:

• La instalación no se ralentiza ni se ve alterada por otros programas en ejecución, AVP, etc.

• No hay que lidiar con la interfaz de usuario, hacer clic, etc. Es más rápido. Cuando termina, en caso de reinicio, el ordenador está listo para funcionar.

Por desgracia, no parece haber forma de hacerlo con las herramientas proporcionadas por Microsoft. Yo utilizo esta utilidad gratuita que lo hará por ti. He creado un acceso directo con los siguientes parámetros y lo he colocado en mi menú del botón Inicio:

ShutdownWithUpdates /r /f

Por lo que veo también puede reiniciar e instalar actualizaciones en una estación de trabajo remota en una configuración de directorio activo.

Más información .

Esto aparece muy arriba en la búsqueda de Google "Instalar y Reiniciar no Instalar y Apagar". Por lo tanto, pensé que debía añadir una solución que terminé escribiendo para este problema molesto exacta (la gente me dice que Win10 tiene esto por defecto, pero no estoy en Win10).

Esto funciona utilizando dos archivos por lotes. El primero se llama "rebootAfterUpdates.bat"

@echo OFF
@setlocal ENABLEEXTENSIONS
@set REBOOT_KEY="HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\WindowsUpdate\Auto Update\RebootRequired"
@SET REGDWORD=REG_DWORD
@SET VALUEVAL=0x1

@REM skip=4 may be required on some versions of Windows
@FOR /F "usebackq skip=2 tokens=1-3" %%A IN (`reg query %REBOOT_KEY% /s 2^>nul`) DO (
    @IF %%B EQU %REGDWORD% (
        @IF %%C EQU %VALUEVAL% (
            call :REBOOT
        )
    )
)

:NOREBOOT
@Echo No reboot required
exit /b 36877
REM 36877 is 0x900D (i.e. Good, no reboot required)
:REBOOT
@ECHO Here We REBOOT
SHUTDOWN -r -f -t 10
exit /b 3059719
REM 3059719 is 0x2EB007 (i.e. REBOOT was triggered)

El segundo se llama "scheduleRebootAfterUpdates.bat":

@schtasks /query /TN RebootAfterUpdates > doh
@findstr /B /I "RebootAfterUpdates" doh >nul
@if %errorlevel%==0  goto :update
@goto :create

:update
@del doh
@SCHTASKS /Change /TN RebootAfterUpdates /SD %DATE%
@echo Task updated to execute today
@goto :exitBat

:create
@del doh
@SCHTASKS /Create /SC ONCE  /TN RebootAfterUpdates /TR "C:\tmp\Scripts\rebootAfterUpdates.bat" /ST 23:55 /sd %DATE%  /ru SYSTEM /f
@echo Task created. Set the "Wake to Execute Flag" through Task Scheduler GUI

:exitBat
@exit /b

Se supone que ambos archivos están en C:\tmp\<strkeep>scripts<strkeep>\ Cuando Windows te pida "Instalar actualizaciones", deja que empiece a instalarlas. Mientras instala las actualizaciones, ejecute "scheduleRebootAfterUpdates.bat".

Antecedentes de la operación:

Si las actualizaciones requieren un reinicio, algunas claves del registro (bajo la clave reg WindowsUpdate) se establecen con el valor 0x1.

Comprobamos si estas claves existen en el primer archivo bat. Si lo hacen, reinicie inmediatamente.

Normalmente, activo las actualizaciones cuando estoy a punto de salir del trabajo (y unas 4-5 horas antes de medianoche).

El segundo bat crea una tarea programada (o actualiza una tarea existente para que se ejecute 5 min antes de medianoche) y esta tarea programada ejecuta el primer bat.

Así que... aunque no es la solución más elegante, en dos pasos (1. activar 'Instalar actualizaciones' y 2. ejecutar el segundo archivo bat), tu máquina se reiniciará cerca de medianoche asumiendo que la instalación de las actualizaciones tuvo éxito.

Además, puede configurar la opción "Despertar la máquina para ejecutar la tarea" desde la GUI del Programador de Tareas, así como comprobar el código de retorno de la ejecución para ver qué ocurrió la última vez.

P.D. Probado en Win7 64bit.

No hay forma de iniciar una "Instalación de actualizaciones y reinicio" manualmente. Podrías establecer un tiempo para que las actualizaciones se instalen, y luego especificar que la máquina puede reiniciarse después de las Actualizaciones Automáticas, ya sea a través del panel de control de Actualizaciones Automáticas (o Windows Update), directamente a través del registro, o a través de la Directiva de Grupo:

http://support.microsoft.com/kb/328010

Pero en cuanto a la opción "Instalar actualizaciones y reiniciar" con un solo clic, no existe.